1 (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7         ((assignment? exp) (eval-assignment exp env))
8         ((definition? exp) (eval-definition exp env))
9         ((if? exp) (eval-if exp env))
10 	((and? exp) (eval-and exp env))
11 	((or? exp) (eval-or exp env))
12         ((lambda? exp)
13          (make-procedure (lambda-parameters exp)
14                          (lambda-body exp)
15                          env))
16         ((begin? exp) 
17          (eval-sequence (begin-actions exp) env))
18         ((cond? exp) (eval (cond->if exp) env))
19 	((let? exp) (eval (let->combination exp) env))
20 	((let*? exp) (eval (let*->nested-lets exp) env))
21 	((named-let? exp) (eval (named-let->combination exp) env))
22 	((do? exp) (eval (do->combination exp) env))
23         ((application? exp)
24          (apply (eval (operator exp) env)
25                 (list-of-values (operands exp) env)))
26         (else
27          (error "Unknown expression type -- EVAL" exp))))
28 (define (apply procedure arguments)
29   (cond ((primitive-procedure? procedure)
30          (apply-primitive-procedure procedure arguments))
31         ((compound-procedure? procedure)
32          (eval-sequence
33            (procedure-body procedure)
34            (extend-environment
35              (procedure-parameters procedure)
36              arguments
37              (procedure-environment procedure))))
38         (else
39          (error
40           "Unknown procedure type -- APPLY" procedure))))
41 
42 (define (list-of-values exps env)
43   (if (no-operands? exps)
44       '()
45       (cons (eval (first-operand exps) env)
46             (list-of-values (rest-operands exps) env))))
47 
48 (define (tagged-list? exp tag)
49   (if (pair? exp)
50       (eq? (car exp) tag)
51       false))
52 
53 ;; self-evaluating/variable/quoted
54 (define (self-evaluating? exp)
55   (cond ((number? exp) true)
56         ((string? exp) true)
57         (else false)))
58 (define (variable? exp) (symbol? exp))
59 (define (quoted? exp)
60   (tagged-list? exp 'quote))
61 (define (text-of-quotation exp) (cadr exp))
62 
63 ;; assignment/definition
64 (define (assignment? exp)
65   (tagged-list? exp 'set!))
66 (define (assignment-variable exp) (cadr exp))
67 (define (assignment-value exp) (caddr exp))
68 (define (definition? exp)
69   (tagged-list? exp 'define))
70 (define (definition-variable exp)
71   (if (symbol? (cadr exp))
72       (cadr exp)
73       (caadr exp)))
74 (define (definition-value exp)
75   (if (symbol? (cadr exp))
76       (caddr exp)
77       (make-lambda (cdadr exp)   ; formal parameters
78                    (cddr exp)))) ; body
79 (define (eval-assignment exp env)
80   (set-variable-value! (assignment-variable exp)
81                        (eval (assignment-value exp) env)
82                        env)
83   'ok)
84 (define (eval-definition exp env)
85   (define-variable! (definition-variable exp)
86                     (eval (definition-value exp) env)
87                     env)
88   'ok)
89 (define (make-definition var val)
90   `(define ,var ,val))
91 
92 
93 ;; if/and/or
94 (define (if? exp) (tagged-list? exp 'if))
95 (define (if-predicate exp) (cadr exp))
96 (define (if-consequent exp) (caddr exp))
97 (define (if-alternative exp)
98   (if (not (null? (cdddr exp)))
99       (cadddr exp)
100       'false))
101 (define (make-if predicate consequent alternative)
102   (list 'if predicate consequent alternative))
103 (define (eval-if exp env)
104   (if (true? (eval (if-predicate exp) env))
105       (eval (if-consequent exp) env)
106       (eval (if-alternative exp) env)))
107 
108 (define (and? exp)
109   (tagged-list? exp 'and))
110 (define (and-clauses exp)
111   (cdr exp))
112 (define (or? exp)
113   (tagged-list? exp 'or))
114 (define (or-clauses exp)
115   (cdr exp))
116 (define (eval-and exp env)
117   (define (eval-clauses clauses)
118     (cond ((null? clauses) true)
119 	  ((null? (cdr clauses)) (eval (car clauses) env))
120 	  (else (and (eval (car clauses) env)
121 		     (eval-clauses (cdr clauses))))))
122   (eval-clauses (and-clauses exp)))
123 (define (eval-or exp env)
124   (define (eval-clauses clauses)
125     (if (null? clauses)
126 	false
127 	(or (eval (car clauses) env)
128 	    (eval-clauses (cdr clauses)))))
129   (eval-clauses (or-clauses exp)))
130 
131 
132 ;; lambda/let/let*
133 (define (lambda? exp) (tagged-list? exp 'lambda))
134 (define (lambda-parameters exp) (cadr exp))
135 (define (lambda-body exp) (cddr exp))
136 (define (make-lambda parameters body)
137   (cons 'lambda (cons parameters body)))
138 
139 (define (make-let vars vals body)
140   (cons 'let
141 	(cons (map list vars vals)
142 	      body)))
143 (define (let? exp)
144   (and (tagged-list? exp 'let)
145        (not (symbol? (cadr exp)))))
146 (define (let-vars exp)
147   (map car (cadr exp)))
148 (define (let-vals exp)
149   (map cadr (cadr exp)))
150 (define (let-body exp)
151   (cddr exp))
152 (define (let->combination exp)
153   (make-application (make-lambda (let-vars exp) (let-body exp))
154 		    (let-vals exp)))
155 (define (named-let? exp)
156   (and (tagged-list? exp 'let)
157        (symbol? (cadr exp))))
158 (define (named-let-name exp)
159   (cadr exp))
160 (define (named-let-vars exp)
161   (map car (caddr exp)))
162 (define (named-let-vals exp)
163   (map cadr (caddr exp)))
164 (define (named-let-body exp)
165   (cdddr exp))
166 (define (named-let->combination exp)
167   (sequence->exp
168    (list (make-definition (named-let-name exp)
169 			  (make-lambda (named-let-vars exp)
170 				       (named-let-body exp)))
171 	 (make-application (named-let-name exp)
172 			   (named-let-vals exp)))))
173 (define (make-named-let name vars vals body)
174   (cons 'let 
175 	(cons name
176 	      (cons (map list vars vals)
177 		    body))))
178 
179 (define (make-application op args)
180   (cons op args))
181 
182 (define (let*? exp)
183   (tagged-list? exp 'let*))
184 (define let*-vars let-vars)
185 (define let*-vals let-vals)
186 (define let*-body let-body)
187 (define (let*->nested-lets exp)
188   (define (expand-lets vars vals)
189     (if (null? (cdr vars))
190 	(make-let (list (car vars)) 
191 		  (list (car vals))
192 		  (let*-body exp))
193 	(make-let (list (car vars))
194 		  (list (car vals))
195 		  (list (expand-lets (cdr vars) (cdr vals))))))
196   (let ((vars (let*-vars exp))
197 	(vals (let*-vals exp)))
198     (if (null? vars)
199 	(sequence->exp (let*-body exp))
200 	(expand-lets vars vals))))
201 
202 ;; do loop
203 (define (do? exp)
204   (tagged-list? exp 'do))
205 (define (do-vars exp)
206   (map car (cadr exp)))
207 (define (do-inits exp)
208   (map cadr (cadr exp)))
209 (define (do-steps exp)
210   (map (lambda (var-init-step)
211 	 (if (null? (cddr var-init-step))
212 	     (car var-init-step)
213 	     (caddr var-init-step)))
214        (cadr exp)))
215 (define (do-test exp)
216   (caaddr exp))
217 (define (do-expressions exp)
218   (if (null? (cdaddr exp))
219       (caddr exp)
220       (cdaddr exp)))
221 (define (do-commands exp)
222   (cdddr exp))
223 (define (do->combination exp)
224   (make-named-let
225    'do-iter
226    (do-vars exp)
227    (do-inits exp)
228    (list
229     (make-if
230      (do-test exp)
231      (sequence->exp (do-expressions exp))
232      (sequence->exp
233       (append (do-commands exp)
234 	      (list (make-application
235 		     'do-iter
236 		     (do-steps exp)))))))))
237 
238 
239 ;; begin/sequence
240 (define (begin? exp) (tagged-list? exp 'begin))
241 (define (begin-actions exp) (cdr exp))
242 (define (last-exp? seq) (null? (cdr seq)))
243 (define (first-exp seq) (car seq))
244 (define (rest-exps seq) (cdr seq))
245 (define (sequence->exp seq)
246   (cond ((null? seq) seq)
247         ((last-exp? seq) (first-exp seq))
248         (else (make-begin seq))))
249 (define (make-begin seq) (cons 'begin seq))
250 (define (eval-sequence exps env)
251   (cond ((last-exp? exps) (eval (first-exp exps) env))
252         (else (eval (first-exp exps) env)
253               (eval-sequence (rest-exps exps) env))))
254 
255 ;; application
256 (define (application? exp) (pair? exp))
257 (define (operator exp) (car exp))
258 (define (operands exp) (cdr exp))
259 (define (no-operands? ops) (null? ops))
260 (define (first-operand ops) (car ops))
261 (define (rest-operands ops) (cdr ops))
262 
263 ;; cond
264 (define (cond? exp) (tagged-list? exp 'cond))
265 (define (cond-clauses exp) (cdr exp))
266 (define (cond-else-clause? clause)
267   (eq? (cond-predicate clause) 'else))
268 (define (cond-predicate clause) (car clause))
269 (define (cond-actions clause) (cdr clause))
270 (define (cond-extended-clause? clause)
271   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
272 (define (cond-extended-proc clause)
273   (caddr clause))
274 (define (cond->if exp)
275   (expand-clauses (cond-clauses exp)))
276 (define (expand-clauses clauses)
277   (if (null? clauses)
278       'false                          ; no else clause
279       (let ((first (car clauses))
280             (rest (cdr clauses)))
281         (if (cond-else-clause? first)
282             (if (null? rest)
283                 (sequence->exp (cond-actions first))
284                 (error "ELSE clause isn't last -- COND->IF"
285                        clauses))
286 	    (if (cond-extended-clause? first)
287 		(make-if (cond-predicate first)
288 			 (make-application
289 			  (cond-extended-proc first)
290 			  (list (cond-predicate first)))
291 			 (expand-clauses rest))
292 		(make-if (cond-predicate first)
293 			 (sequence->exp (cond-actions first))
294 			 (expand-clauses rest)))))))
295 (define (true? x)
296   (not (eq? x false)))
297 (define (false? x)
298   (eq? x false))
299 
300 ;; procedure
301 (define (make-procedure parameters body env)
302   (list 'procedure parameters body env))
303 (define (compound-procedure? p)
304   (tagged-list? p 'procedure))
305 (define (procedure-parameters p) (cadr p))
306 (define (procedure-body p) (caddr p))
307 (define (procedure-environment p) (cadddr p))
308 
309 ;; environment
310 (define (enclosing-environment env) (cdr env))
311 (define (first-frame env) (car env))
312 (define the-empty-environment '())
313 (define (make-frame variables values)
314   (map cons variables values))
315 ;; (define (set-first-frame! env frame)
316 ;;   (set-car! env frame))
317 (define (binding-var binding)
318   (car binding))
319 (define (binding-val binding)
320   (cdr binding))
321 (define (make-binding var val)
322   (cons var val))
323 ;; (define (frame-variables frame) (map car frame))
324 ;; (define (frame-values frame) (map cdr frame))
325 (define (add-binding-to-first-frame! var val env)
326   (set-car! env (cons (make-binding var val) (first-frame env))))
327 (define (extend-environment vars vals base-env)
328   (if (= (length vars) (length vals))
329       (cons (make-frame vars vals) base-env)
330       (if (< (length vars) (length vals))
331           (error "Too many arguments supplied" vars vals)
332           (error "Too few arguments supplied" vars vals))))
333 (define (lookup-variable-value var env)
334   (define (env-loop env)
335     (define (scan bindings)
336       (cond ((null? bindings)
337              (env-loop (enclosing-environment env)))
338             ((eq? (binding-var (car bindings)) var)
339              (binding-val (car bindings)))
340             (else (scan (cdr bindings)))))
341     (if (eq? env the-empty-environment)
342         (error "Unbound variable" var)
343 	(scan (first-frame env))))
344   (env-loop env))
345 (define (set-variable-value! var val env)
346   (define (env-loop env)
347     (define (scan bindings)
348       (cond ((null? bindings)
349              (env-loop (enclosing-environment env)))
350             ((eq? var (binding-var (car bindings)))
351              (set-cdr! (car bindings) val))
352             (else (scan (cdr bindings)))))
353     (if (eq? env the-empty-environment)
354         (error "Unbound variable -- SET!" var)
355 	(scan (first-frame env))))
356   (env-loop env))
357 (define (define-variable! var val env)
358   (let ((frame (first-frame env)))
359     (define (scan bindings)
360       (cond ((null? bindings)
361 	     (add-binding-to-first-frame! var val env))
362             ((eq? var (binding-var (car bindings)))
363              (set-cdr! (car bindings) val))
364             (else (scan (cdr bindings)))))
365     (scan (first-frame env))))
366 
367 ;; primitives
368 (define (primitive-procedure? proc)
369   (tagged-list? proc 'primitive))
370 (define (primitive-implementation proc) (cadr proc))
371 (define primitive-procedures
372   (list (list 'car car)
373         (list 'cdr cdr)
374 	(list 'caar caar)
375 	(list 'cadr cadr)
376 	(list 'cddr cddr)
377         (list 'cons cons)
378         (list 'null? null?)
379 	(list '* *)
380 	(list '/ /)
381 	(list '+ +)
382 	(list '- -)
383 	(list '= =)
384 	(list '< <)
385 	(list '> >)
386 	(list '<= <=)
387 	(list '>= >=)
388 	(list 'remainder remainder)
389 	(list 'eq? eq?)
390 	(list 'equal? equal?)
391 	(list 'display display)))
392 (define (primitive-procedure-names)
393   (map car
394        primitive-procedures))
395 (define (primitive-procedure-objects)
396   (map (lambda (proc) (list 'primitive (cadr proc)))
397        primitive-procedures))
398 (define (apply-primitive-procedure proc args)
399   (apply-in-underlying-scheme
400    (primitive-implementation proc) args))
401 
402 ;; driver-loop
403 (define input-prompt ";;; M-Eval input:")
404 (define output-prompt ";;; M-Eval value:")
405 (define (driver-loop)
406   (prompt-for-input input-prompt)
407   (let ((input (read)))
408     (let ((output (eval input the-global-environment)))
409       (announce-output output-prompt)
410       (user-print output)))
411   (driver-loop))
412 (define (prompt-for-input string)
413   (newline) (newline) (display string) (newline))
414 
415 (define (announce-output string)
416   (newline) (display string) (newline))
417 (define (user-print object)
418   (if (compound-procedure? object)
419       (display (list 'compound-procedure
420                      (procedure-parameters object)
421                      (procedure-body object)
422                      '<procedure-env>))
423       (display object)))
424 (define (setup-environment)
425   (let ((initial-env
426          (extend-environment (primitive-procedure-names)
427                              (primitive-procedure-objects)
428                              the-empty-environment)))
429     (define-variable! 'true true initial-env)
430     (define-variable! 'false false initial-env)
431     initial-env))
432 (define the-global-environment (setup-environment))
433 
434 ;; auxiliary
435 (define (test-case actual expected)
436   (newline)
437   (display "Actual:   ")
438   (display actual)
439   (newline)
440   (display "Expected: ")
441   (display expected)
442   (newline))
443 (define (geval exp) ;; eval globally
444   (eval exp the-global-environment))
445 (define (test-eval exp expected)
446   (test-case (geval exp) expected))
447 
448 ;; Exercise 4.11.  Instead of representing a frame as a pair of lists, we can represent a frame as a list of bindings, where each binding is a name-value pair. Rewrite the environment operations to use this alternative representation. 
449 
450 
451 ;; test-suite
452 
453 ;; procedure definitions
454 
455 (geval 
456  '(define (assoc key records)
457     (cond ((null? records) false)
458 	  ((equal? key (caar records)) (car records))
459 	  (else (assoc key (cdr records))))))
460 
461 (geval
462  '(define (map proc list)
463     (if (null? list)
464 	'()
465 	(cons (proc (car list))
466 	      (map proc (cdr list))))))
467 
468 (geval 
469  '(define (accumulate op initial sequence)
470     (if (null? sequence)
471 	initial
472 	(op (car sequence)
473 	    (accumulate op initial (cdr sequence))))))
474 
475 ;; all special forms
476 (test-eval '(begin 5 6) 6)
477 (test-eval '10 10)
478 (geval '(define x 3))
479 (test-eval 'x 3)
480 (test-eval '(set! x -25) 'ok)
481 (test-eval 'x -25)
482 (geval '(define z (lambda (x y) (+ x (* x y)))))
483 (test-eval '(z 3 4) 15)
484 (test-eval '(cond ((= x -2) 'x=-2)
485 		  ((= x -25) 'x=-25)
486 		  (else 'failed))
487 	   'x=-25)
488 (test-eval '(if true false true) false)
489 (test-eval 
490  '(let ((x 4) (y 7))
491     (+ x y (* x y)))
492  (+ 4 7 (* 4 7)))
493 
494 
495 ;; and/or
496 (geval '(define x (+ 3 8)))
497 (test-eval '(and 0 true x) 11)
498 (test-eval '(and 0 true x false) false)
499 (test-eval '(and 0 true x (set! x -2) false) false)
500 (test-eval 'x -2)
501 (test-eval '(and 0 true x false (set! x -5)) false)
502 (test-eval 'x -2)
503 (test-eval '(or false (set! x 25)) 'ok)
504 (test-eval 'x 25)
505 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
506 (test-eval 'x 2)
507 (test-eval '(or false (set! x 25) true false) 'ok)
508 (test-eval 'x 25)
509 (test-eval '(or ((lambda (x) x) 5)) 5)
510 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
511 
512 
513 ;; cond
514 
515 (test-eval 
516  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
517 	(else false))
518  2)
519 
520 (test-eval
521  '(cond ((= 3 4) 'not-true)
522 	((= (* 2 4) 3) 'also-false)
523 	((map (lambda (x)
524 		(* x (+ x 1)))
525 	      '(2 4 1 9))
526 	 =>
527 	 (lambda (x)
528 	   (accumulate + 0 x)))
529 	(else 'never-reach))
530  118)
531 ;; '(6 20 2 90)
532 
533 
534 ;; procedure definition and application
535 (geval
536  '(define (factorial n)
537     (if (= n 0)
538 	1
539 	(* n (factorial (- n 1))))))
540 (test-eval '(factorial 5) 120)
541 
542 ;; map
543 
544 (test-eval
545  '(map (lambda (x)
546 	 (* x (+ x 1)))
547        '(2 1 4 2 8 3))
548  '(6 2 20 6 72 12))
549 ;; accumulate
550 
551 (test-eval
552  '(accumulate + 0 '(1 2 3 4 5))
553  15)
554 
555 ;; make-let
556 (test-eval 
557  (make-let '(x y) '(3 5) '((+ x y)))
558  8)
559 (test-eval 
560  '(let ()
561     5)
562  5)
563 (test-eval
564  '(let ((x 3))
565     x)
566  3)
567 (test-eval
568  '(let ((x 3)
569 	(y 5))
570     (+ x y))
571  8)
572 (test-eval 
573  '(let ((x 3)
574 	(y 2))
575     (+ (let ((x (+ y 2))
576 	     (y x))
577 	 (* x y))
578        x y))
579  (+ (* 4 3) 3 2))
580 (test-eval
581  '(let ((x 6)
582 	(y (let ((x 2))
583 	     (+ x 3)))
584 	(z (let ((a (* 3 2)))
585 	     (+ a 3))))
586     (+ x y z))
587  (+ 6 5 9))
588     
589 
590 ;; let*
591 
592 (test-eval
593  '(let* ((x 3)
594 	 (y (+ x 2))
595 	 (z (+ x y 5)))
596     (* x z))
597  39)
598 
599 (test-eval
600  '(let* ()
601     5)
602  5)
603 (test-eval
604  '(let* ((x 3))
605     (let* ((y 5))
606       (+ x y)))
607  8)
608 
609 (test-eval 
610  '(let* ((x 3)
611 	 (y (+ x 1)))
612     (+ (let* ((x (+ y 2))
613 	      (y x))
614 	 (* x y))
615        x y))
616  (+ (* 6 6) 3 4))
617 (test-eval
618  '(let* ((x 6)
619 	 (y (let* ((x 2)
620 		   (a (let* ((x (* 3 x)))
621 			(+ x 2))))       
622 	      (+ x a)))                  
623 	 (z (+ x y)))                    
624     (+ x y z))
625  32)
626 
627 ;; named-let
628 
629 (test-eval
630  '(let eight ()
631     5
632     7
633     8)
634  8)
635 (test-eval
636  '(let loop ((count 0))
637     (if (= 100 count)
638 	count
639 	(loop (+ count 1))))
640  100)
641 (geval
642  '(define (prime? x)
643     (let prime-iter ((i 2))
644       (cond ((> (* i i) x) true)
645 	    ((= (remainder x i) 0) false)
646 	    (else (prime-iter (+ i 1)))))))
647 (test-eval
648  '(let primes ((x 2)
649 	       (n 20))
650     (cond ((= n 0) '())
651 	  ((prime? x) 
652 	   (cons x
653 		 (primes (+ x 1) (- n 1))))
654 	  (else (primes (+ x 1) n))))
655  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
656 
657 (geval
658  '(define (fib n)
659     (let fib-iter ((a 1)
660 		   (b 0)
661 		   (count n))
662       (if (= count 0)
663 	  b
664 	  (fib-iter (+ a b) a (- count 1))))))
665 (test-eval '(fib 19) 4181)
666 
667 ;; do-loop	  
668 (test-eval
669  '(let ((y 0))
670     (do ((x 0 (+ x 1)))
671 	((= x 5) y)
672       (set! y (+ y 1))))
673  5)
674 (test-eval
675  '(do ()
676       (true))
677  true)
678 (test-eval
679  '(do ()
680       (true 5))
681  5)
682 (test-eval
683  '(let ((y 0))
684     (do ()
685 	((= y 5) y)
686       (set! y (+ y 1))))
687  5)
688 
689 (test-eval
690  '(do ((y '(1 2 3 4)))
691       ((null? y))
692     (set! y (cdr y)))
693  true)
694 (test-eval
695  '(let ((y 0))
696     (do ((x 0 (+ x 1)))
697 	((= x 5) y)
698       (set! y (+ y 1))))
699  5)
700 (test-eval
701  '(let ((x '(1 3 5 7 9)))
702     (do ((x x (cdr x))
703 	 (sum 0 (+ sum (car x))))
704 	((null? x) sum)))
705  25)
706 (test-eval 
707  '(let ((z '()))
708     (do ((x '(1 2 3 4) (cdr x))
709 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
710 	((null? x) y x z)
711       (set! z (cons (car x) z))))
712  '(4 3 2 1))
713 
714 
715