1 ;; (define apply-in-underlying-scheme apply)
2 
3 (define (eval exp env)
4   (cond ((self-evaluating? exp) exp)
5         ((variable? exp) (lookup-variable-value exp env))
6         ((quoted? exp) (text-of-quotation exp))
7 	((quoted-list? exp) (eval (list->cons (text-of-quotation exp)) env))
8         ((assignment? exp) (eval-assignment exp env))
9         ((definition? exp) (eval-definition exp env))
10 ;;	((unbound? exp) (eval-unbound exp env))
11         ((if? exp) (eval-if exp env))
12 	((and? exp) (eval-and exp env))
13 	((or? exp) (eval-or exp env))
14         ((lambda? exp)
15          (make-procedure (lambda-parameters exp)
16                          (lambda-body exp)
17                          env))
18         ((begin? exp) 
19          (eval-sequence (begin-actions exp) env))
20         ((cond? exp) (eval (cond->if exp) env))
21 	((let? exp) (eval (let->combination exp) env))
22 	((let*? exp) (eval (let*->nested-lets exp) env))
23 	((named-let? exp) (eval (named-let->combination exp) env))
24 	((letrec? exp) (eval (letrec->let exp) env))
25 	((do? exp) (eval (do->combination exp) env))
26         ((application? exp)
27          (apply (actual-value (operator exp) env)
28                 (operands exp)
29 		env))
30         (else
31          (error "Unknown expression type -- EVAL" exp))))
32 (define (apply procedure arguments env)
33   (cond ((primitive-procedure? procedure)
34          (apply-primitive-procedure 
35 	  procedure 
36 	  (list-of-arg-values arguments env)))
37         ((compound-procedure? procedure)
38          (eval-sequence
39            (procedure-body procedure)
40            (extend-environment
41              (procedure-parameters procedure)
42              (list-of-delayed-args arguments env)
43              (procedure-environment procedure))))
44         (else
45          (error
46           "Unknown procedure type -- APPLY" procedure))))
47 
48 (define (thunk? obj)
49   (tagged-list? obj 'thunk))
50 (define (thunk-exp thunk)
51   (cadr thunk))
52 (define (thunk-env thunk)
53   (caddr thunk))
54 (define (evaluated-thunk? obj)
55   (tagged-list? obj 'evaluated-thunk))
56 (define (thunk-value evaluated-thunk)
57   (cadr evaluated-thunk))
58 (define (delay-it exp env)
59   `(thunk ,exp ,env))
60 (define (actual-value exp env)
61   (force-it (eval exp env)))
62 (define (force-it obj)
63   (cond ((thunk? obj)
64 	 (let ((result (actual-value 
65 			(thunk-exp obj)
66 			(thunk-env obj))))
67 	   (set-car! obj 'evaluated-thunk)
68 	   (set-car! (cdr obj) result)
69 	   (set-cdr! (cdr obj) '())
70 	   result))
71 	((evaluated-thunk? obj)
72 	 (thunk-value obj))
73 	(else obj)))
74 
75 (define (list-of-arg-values exps env)
76   (if (no-operands? exps)
77       '()
78       (cons (actual-value (first-operand exps) env)
79             (list-of-arg-values (rest-operands exps) env))))
80 (define (list-of-delayed-args exps env)
81   (if (no-operands? exps)
82       '()
83       (cons (delay-it (first-operand exps) env)
84 	    (list-of-delayed-args (rest-operands exps) env))))
85 
86 (define (tagged-list? exp tag)
87   (if (pair? exp)
88       (eq? (car exp) tag)
89       false))
90 
91 ;; self-evaluating/variable/quoted
92 (define (self-evaluating? exp)
93   (cond ((number? exp) true)
94         ((string? exp) true)
95         (else false)))
96 (define (variable? exp) (symbol? exp))
97 (define (quoted? exp)
98   (and (tagged-list? exp 'quote)
99        (not (pair? (cadr exp)))))
100 (define (text-of-quotation exp) (cadr exp))
101 
102 ;; assignment/definition
103 (define (assignment? exp)
104   (tagged-list? exp 'set!))
105 (define (assignment-variable exp) (cadr exp))
106 (define (assignment-value exp) (caddr exp))
107 (define (make-assignment var val)
108   (list 'set! var val))
109 (define (definition? exp)
110   (tagged-list? exp 'define))
111 (define (definition-variable exp)
112   (if (symbol? (cadr exp))
113       (cadr exp)
114       (caadr exp)))
115 (define (definition-value exp)
116   (if (symbol? (cadr exp))
117       (caddr exp)
118       (make-lambda (cdadr exp)   ; formal parameters
119                    (cddr exp)))) ; body
120 (define (eval-assignment exp env)
121   (set-variable-value! (assignment-variable exp)
122                        (eval (assignment-value exp) env)
123                        env)
124   'ok)
125 (define (eval-definition exp env)
126   (define-variable! (definition-variable exp)
127                     (eval (definition-value exp) env)
128                     env)
129   'ok)
130 (define (make-definition var val)
131   `(define ,var ,val))
132 
133 ;; make-unbound!
134 
135 ;; (define (unbound? exp)
136 ;;   (tagged-list? exp 'make-unbound!))
137 ;; (define (unbound-var exp)
138 ;;   (cadr exp))
139 ;; (define (eval-unbound exp env)
140 ;;   (remove-binding-from-frame! (unbound-var exp) (first-frame env)))
141 
142 
143 
144 ;; if/and/or
145 (define (if? exp) (tagged-list? exp 'if))
146 (define (if-predicate exp) (cadr exp))
147 (define (if-consequent exp) (caddr exp))
148 (define (if-alternative exp)
149   (if (not (null? (cdddr exp)))
150       (cadddr exp)
151       'false))
152 (define (make-if predicate consequent alternative)
153   (list 'if predicate consequent alternative))
154 (define (eval-if exp env)
155   (if (true? (actual-value (if-predicate exp) env))
156       (eval (if-consequent exp) env)
157       (eval (if-alternative exp) env)))
158 
159 (define (and? exp)
160   (tagged-list? exp 'and))
161 (define (and-clauses exp)
162   (cdr exp))
163 (define (or? exp)
164   (tagged-list? exp 'or))
165 (define (or-clauses exp)
166   (cdr exp))
167 (define (eval-and exp env)
168   (define (eval-clauses clauses)
169     (cond ((null? clauses) true)
170 	  ((null? (cdr clauses)) (eval (car clauses) env))
171 	  (else (and (eval (car clauses) env)
172 		     (eval-clauses (cdr clauses))))))
173   (eval-clauses (and-clauses exp)))
174 (define (eval-or exp env)
175   (define (eval-clauses clauses)
176     (if (null? clauses)
177 	false
178 	(or (eval (car clauses) env)
179 	    (eval-clauses (cdr clauses)))))
180   (eval-clauses (or-clauses exp)))
181 
182 
183 ;; lambda/let/let*/letrec
184 (define (lambda? exp) (tagged-list? exp 'lambda))
185 (define (lambda-parameters exp) (cadr exp))
186 (define (lambda-body exp) (cddr exp))
187 (define (make-lambda parameters body)
188   (cons 'lambda (cons parameters body)))
189 
190 (define (make-let vars vals body)
191   (cons 'let
192 	(cons (map list vars vals)
193 	      body)))
194 (define (let? exp)
195   (and (tagged-list? exp 'let)
196        (not (symbol? (cadr exp)))))
197 (define (let-vars exp)
198   (map car (cadr exp)))
199 (define (let-vals exp)
200   (map cadr (cadr exp)))
201 (define (let-body exp)
202   (cddr exp))
203 (define (let->combination exp)
204   (make-application (make-lambda (let-vars exp) (let-body exp))
205 		    (let-vals exp)))
206 (define (named-let? exp)
207   (and (tagged-list? exp 'let)
208        (symbol? (cadr exp))))
209 (define (named-let-name exp)
210   (cadr exp))
211 (define (named-let-vars exp)
212   (map car (caddr exp)))
213 (define (named-let-vals exp)
214   (map cadr (caddr exp)))
215 (define (named-let-body exp)
216   (cdddr exp))
217 (define (named-let->combination exp)
218   (sequence->exp
219    (list (make-definition (named-let-name exp)
220 			  (make-lambda (named-let-vars exp)
221 				       (named-let-body exp)))
222 	 (make-application (named-let-name exp)
223 			   (named-let-vals exp)))))
224 (define (make-named-let name vars vals body)
225   (cons 'let 
226 	(cons name
227 	      (cons (map list vars vals)
228 		    body))))
229 
230 (define (letrec? exp)
231   (tagged-list? exp 'letrec))
232 
233 (define (letrec-vars exp)
234   (map car (cadr exp)))
235 (define (letrec-vals exp)
236   (map cadr (cadr exp)))
237 (define (letrec-body exp)
238   (cddr exp))
239 (define (letrec->let exp)
240   (let* ((vars (letrec-vars exp))
241 	 (unassigneds (map (lambda (var) ''*unassigned*)
242 			   vars))
243 	 (vals (letrec-vals exp))
244 	 (assignments (map (lambda (var val)
245 			     (make-assignment var val))
246 			   vars
247 			   vals))
248 	 (body (letrec-body exp)))
249   (make-let vars 
250 	    unassigneds
251 	    (append assignments body))))
252 
253 
254 
255 
256 (define (let*? exp)
257   (tagged-list? exp 'let*))
258 (define let*-vars let-vars)
259 (define let*-vals let-vals)
260 (define let*-body let-body)
261 (define (let*->nested-lets exp)
262   (define (expand-lets vars vals)
263     (if (null? (cdr vars))
264 	(make-let (list (car vars)) 
265 		  (list (car vals))
266 		  (let*-body exp))
267 	(make-let (list (car vars))
268 		  (list (car vals))
269 		  (list (expand-lets (cdr vars) (cdr vals))))))
270   (let ((vars (let*-vars exp))
271 	(vals (let*-vals exp)))
272     (if (null? vars)
273 	(sequence->exp (let*-body exp))
274 	(expand-lets vars vals))))
275 
276 ;; do loop
277 (define (do? exp)
278   (tagged-list? exp 'do))
279 (define (do-vars exp)
280   (map car (cadr exp)))
281 (define (do-inits exp)
282   (map cadr (cadr exp)))
283 (define (do-steps exp)
284   (map (lambda (var-init-step)
285 	 (if (null? (cddr var-init-step))
286 	     (car var-init-step)
287 	     (caddr var-init-step)))
288        (cadr exp)))
289 (define (do-test exp)
290   (caaddr exp))
291 (define (do-expressions exp)
292   (if (null? (cdaddr exp))
293       (caddr exp)
294       (cdaddr exp)))
295 (define (do-commands exp)
296   (cdddr exp))
297 (define (do->combination exp)
298   (make-named-let
299    'do-iter
300    (do-vars exp)
301    (do-inits exp)
302    (list
303     (make-if
304      (do-test exp)
305      (sequence->exp (do-expressions exp))
306      (sequence->exp
307       (append (do-commands exp)
308 	      (list (make-application
309 		     'do-iter
310 		     (do-steps exp)))))))))
311 
312 
313 ;; begin/sequence
314 (define (begin? exp) (tagged-list? exp 'begin))
315 (define (begin-actions exp) (cdr exp))
316 (define (last-exp? seq) (null? (cdr seq)))
317 (define (first-exp seq) (car seq))
318 (define (rest-exps seq) (cdr seq))
319 (define (sequence->exp seq)
320   (cond ((null? seq) seq)
321         ((last-exp? seq) (first-exp seq))
322         (else (make-begin seq))))
323 (define (make-begin seq) (cons 'begin seq))
324 (define (eval-sequence exps env)
325   (cond ((last-exp? exps) (eval (first-exp exps) env))
326         (else (eval (first-exp exps) env)
327               (eval-sequence (rest-exps exps) env))))
328 
329 ;; application
330 (define (make-application op args)
331   (cons op args))
332 (define (application? exp) (pair? exp))
333 (define (operator exp) (car exp))
334 (define (operands exp) (cdr exp))
335 (define (no-operands? ops) (null? ops))
336 (define (first-operand ops) (car ops))
337 (define (rest-operands ops) (cdr ops))
338 
339 ;; cond
340 (define (cond? exp) (tagged-list? exp 'cond))
341 (define (cond-clauses exp) (cdr exp))
342 (define (cond-else-clause? clause)
343   (eq? (cond-predicate clause) 'else))
344 (define (cond-predicate clause) (car clause))
345 (define (cond-actions clause) (cdr clause))
346 (define (cond-extended-clause? clause)
347   (and (not (null? (cdr clause))) (eq? (cadr clause) '=>)))
348 (define (cond-extended-proc clause)
349   (caddr clause))
350 (define (cond->if exp)
351   (expand-clauses (cond-clauses exp)))
352 (define (expand-clauses clauses)
353   (if (null? clauses)
354       'false                          ; no else clause
355       (let ((first (car clauses))
356             (rest (cdr clauses)))
357         (if (cond-else-clause? first)
358             (if (null? rest)
359                 (sequence->exp (cond-actions first))
360                 (error "ELSE clause isn't last -- COND->IF"
361                        clauses))
362 	    (if (cond-extended-clause? first)
363 		(make-if (cond-predicate first)
364 			 (make-application
365 			  (cond-extended-proc first)
366 			  (list (cond-predicate first)))
367 			 (expand-clauses rest))
368 		(make-if (cond-predicate first)
369 			 (sequence->exp (cond-actions first))
370 			 (expand-clauses rest)))))))
371 (define (true? x)
372   (not (eq? x false)))
373 (define (false? x)
374   (eq? x false))
375 
376 ;; procedure
377 (define (make-procedure parameters body env)
378   (list 'procedure parameters body env))
379 ;; (define (scan-out-defines body)
380 ;;   (let* ((definitions (filter definition? body))
381 ;; 	 (vars (map definition-variable definitions))
382 ;; 	 (unassigneds (map (lambda (var) ''*unassigned*) 
383 ;; 			   vars))
384 ;; 	 (vals (map definition-value definitions))
385 ;; 	 (assignments 
386 ;; 	  (map (lambda (var val)
387 ;; 		 (make-assignment var val))
388 ;; 	       vars vals))
389 ;; 	 (exps (remove definition? body)))
390 ;;     (if (null? definitions)
391 ;; 	body
392 ;; 	(list
393 ;; 	 (make-let vars
394 ;; 		   unassigneds
395 ;; 		   (append assignments exps))))))
396 (define (compound-procedure? p)
397   (tagged-list? p 'procedure))
398 (define (procedure-parameters p) (cadr p))
399 (define (procedure-body p) (caddr p))
400 (define (procedure-environment p) (cadddr p))
401 
402 ;; environment
403 (define (enclosing-environment env) (cdr env))
404 (define (first-frame env) (car env))
405 (define the-empty-environment '())
406 (define (make-frame variables values)
407   (cons variables values))
408 (define (frame-variables frame) (car frame))
409 (define (frame-values frame) (cdr frame))
410 (define (add-binding-to-frame! var val frame)
411   (set-car! frame (cons var (car frame)))
412   (set-cdr! frame (cons val (cdr frame))))
413 (define (extend-environment vars vals base-env)
414   (if (= (length vars) (length vals))
415       (cons (make-frame vars vals) base-env)
416       (if (< (length vars) (length vals))
417           (error "Too many arguments supplied" vars vals)
418           (error "Too few arguments supplied" vars vals))))
419 (define (lookup-variable-value var env)
420   (define (env-loop env)
421     (define (scan vars vals)
422       (cond ((null? vars)
423              (env-loop (enclosing-environment env)))
424             ((eq? var (car vars))
425 	     (let ((val (car vals)))
426 	       (if (eq? val '*unassigned*)
427 		   (error "Var not yet defined -- LOOKUP-VARIABLE-VALUE" var)
428 		   val)))
429             (else (scan (cdr vars) (cdr vals)))))
430     (if (eq? env the-empty-environment)
431         (error "Unbound variable" var)
432         (let ((frame (first-frame env)))
433           (scan (frame-variables frame)
434                 (frame-values frame)))))
435   (env-loop env))
436 (define (set-variable-value! var val env)
437   (define (env-loop env)
438     (define (scan vars vals)
439       (cond ((null? vars)
440              (env-loop (enclosing-environment env)))
441             ((eq? var (car vars))
442              (set-car! vals val))
443             (else (scan (cdr vars) (cdr vals)))))
444     (if (eq? env the-empty-environment)
445         (error "Unbound variable -- SET!" var)
446         (let ((frame (first-frame env)))
447           (scan (frame-variables frame)
448                 (frame-values frame)))))
449   (env-loop env))
450 (define (define-variable! var val env)
451   (let ((frame (first-frame env)))
452     (define (scan vars vals)
453       (cond ((null? vars)
454              (add-binding-to-frame! var val frame))
455             ((eq? var (car vars))
456              (set-car! vals val))
457             (else (scan (cdr vars) (cdr vals)))))
458     (scan (frame-variables frame)
459           (frame-values frame))))
460 
461 (define (remove-binding-from-frame! var frame)
462   (define (scan vars vals)
463     (cond ((null? (cdr vars))
464 	   (error "Binding not found -- REMOVE-BINDING-FROM-FRAME!" var))
465 	  ((eq? var (cadr vars))
466 	   (set-cdr! vars (cddr vars))
467 	   (set-cdr! vals (cddr vals)))
468 	  (else (scan (cdr vars) (cdr vals)))))
469   (let ((vars (frame-variables frame))
470 	(vals (frame-values frame)))
471     (if (eq? var (car vars))
472 	(begin (set-car! frame (cdr vars))
473 	       (set-cdr! frame (cdr vals)))
474 	(scan vars vals))))
475 
476 ;; primitives
477 (define (primitive-procedure? proc)
478   (tagged-list? proc 'primitive))
479 (define (primitive-implementation proc) (cadr proc))
480 (define primitive-procedures
481   (list (list 'car car)
482         (list 'cdr cdr)
483 	(list 'caar caar)
484 	(list 'cadr cadr)
485 	(list 'cddr cddr)
486         (list 'cons cons)
487         (list 'null? null?)
488 	(list '* *)
489 	(list '/ /)
490 	(list '+ +)
491 	(list '- -)
492 	(list '= =)
493 	(list '< <)
494 	(list '> >)
495 	(list '<= <=)
496 	(list '>= >=)
497 	(list 'remainder remainder)
498 	(list 'eq? eq?)
499 	(list 'equal? equal?)
500 	(list 'display display)))
501 (define (primitive-procedure-names)
502   (map car
503        primitive-procedures))
504 (define (primitive-procedure-objects)
505   (map (lambda (proc) (list 'primitive (cadr proc)))
506        primitive-procedures))
507 (define (apply-primitive-procedure proc args)
508   (apply-in-underlying-scheme
509    (primitive-implementation proc) args))
510 
511 ;; driver-loop
512 (define input-prompt ";;; M-Eval input:")
513 (define output-prompt ";;; M-Eval value:")
514 (define (driver-loop)
515   (prompt-for-input input-prompt)
516   (let ((input (read)))
517     (let ((output (actual-value input the-global-environment)))
518       (announce-output output-prompt)
519       (user-print output)))
520   (driver-loop))
521 (define (prompt-for-input string)
522   (newline) (newline) (display string) (newline))
523 
524 (define (announce-output string)
525   (newline) (display string) (newline))
526 (define (user-print object)
527   (if (compound-procedure? object)
528       (display (list 'compound-procedure
529                      (procedure-parameters object)
530                      (procedure-body object)
531                      '<procedure-env>))
532       (display object)))
533 (define (setup-environment)
534   (let ((initial-env
535          (extend-environment (primitive-procedure-names)
536                              (primitive-procedure-objects)
537                              the-empty-environment)))
538     (define-variable! 'true true initial-env)
539     (define-variable! 'false false initial-env)
540     initial-env))
541 (define the-global-environment (setup-environment))
542 
543 ;; auxiliary
544 (define (test-case actual expected)
545   (newline)
546   (display "Actual:   ")
547   (display actual)
548   (newline)
549   (display "Expected: ")
550   (display expected)
551   (newline))
552 (define (geval exp) ;; eval globally
553   (eval exp the-global-environment))
554 (define (test-eval exp expected)
555   (test-case (force-it (geval exp)) expected))
556 
557 ;; Exercise 4.33.  Ben Bitdiddle tests the lazy list implementation given above by evaluating the expression
558 
559 (define (quoted-list? exp)
560   (and (tagged-list? exp 'quote)
561        (pair? (cadr exp))))
562 
563 (define (list->cons exp)
564   (if (pair? exp)
565       (make-cons (list->cons (car exp))
566 		 (list->cons (cdr exp)))
567       (make-quote exp)))
568 (define (make-quote exp)
569   `(quote ,exp))
570 (define (make-cons x y)
571   `(cons ,x ,y))
572 
573 
574 
575 ;; (car '(a b c))
576 
577 ;; if we have a quoted list, we need to transform it into the proper cons
578 
579 ;; To his surprise, this produces an error. After some thought, he realizes that the ``lists'' obtained by reading in quoted expressions are different from the lists manipulated by the new definitions of cons, car, and cdr. Modify the evaluator's treatment of quoted expressions so that quoted lists typed at the driver loop will produce true lazy lists. 
580 
581 ;; (quote (a))
582 (test-eval
583  '(car (cons (quote a) (quote ())))
584  'a)
585 (test-eval
586  '(cdr (cons (quote a) (quote ())))
587  '())
588 (test-eval
589  '(car '(a))
590  'a)
591 (test-eval
592  '(cdr '(a))
593  '())
594 (test-eval
595  '(car (cdr '(a b)))
596  'b)
597 (test-eval
598  '(car (car '((a b) c)))
599  'a)
600 (test-eval
601  '(car (cdr (car (cdr '((a c) (b d))))))
602  'd)
603 
604 
605 
606 ;; cons/car/cdr
607 
608 (geval 
609  '(define (cons x y)
610     (lambda (m) (m x y))))
611 (geval
612  '(define (car z)
613     (z (lambda (p q) p))))
614 (geval
615  '(define (cdr z)
616     (z (lambda (p q) q))))
617 (geval
618  '(define (list-ref items n)
619     (if (= n 0)
620 	(car items)
621 	(list-ref (cdr items) (- n 1)))))
622 (geval
623  '(define (map proc items)
624     (if (null? items)
625 	'()
626 	(cons (proc (car items))
627 	      (map proc (cdr items))))))
628 (geval
629  '(define (scale-list items factor)
630     (map (lambda (x) (* x factor))
631 	 items)))
632 (geval
633  '(define (add-lists list1 list2)
634     (cond ((null? list1) list2)
635 	  ((null? list2) list1)
636 	  (else (cons (+ (car list1) (car list2))
637 		      (add-lists (cdr list1) (cdr list2)))))))
638 
639 
640 
641 (geval 
642  '(define ones (cons 1 ones)))
643 (geval
644  '(define integers (cons 1 (add-lists ones integers))))
645 (test-eval 
646  '(list-ref integers 17)
647  18)
648 
649 (test-eval
650  '(car (cdr (add-lists '(1 2 3 4 5) '(2 3 4 5 6))))
651  5)
652 
653 (geval
654  '(define (integral integrand initial-value dt)
655     (define int
656       (cons initial-value
657 	    (add-lists (scale-list integrand dt)
658 		       int)))
659     int))
660 (geval
661  '(define (solve f y0 dt)
662     (define y (integral dy y0 dt))
663     (define dy (map f y))
664     y))
665 (test-eval 
666  '(list-ref (solve (lambda (x) x) 1 0.001) 1000)
667  2.716924)
668 
669 
670 ;; test-suite
671 
672 ;; procedure definitions
673 
674 (geval 
675  '(define (assoc key records)
676     (cond ((null? records) false)
677 	  ((equal? key (caar records)) (car records))
678 	  (else (assoc key (cdr records))))))
679 
680 (geval
681  '(define (map proc list)
682     (if (null? list)
683 	'()
684 	(cons (proc (car list))
685 	      (map proc (cdr list))))))
686 
687 (geval 
688  '(define (accumulate op initial sequence)
689     (if (null? sequence)
690 	initial
691 	(op (car sequence)
692 	    (accumulate op initial (cdr sequence))))))
693 
694 ;; all special forms
695 (test-eval '(begin 5 6) 6)
696 (test-eval '10 10)
697 (geval '(define x 3))
698 (test-eval 'x 3)
699 (test-eval '(set! x -25) 'ok)
700 (test-eval 'x -25)
701 (geval '(define z (lambda (x y) (+ x (* x y)))))
702 (test-eval '(z 3 4) 15)
703 (test-eval '(cond ((= x -2) 'x=-2)
704 		  ((= x -25) 'x=-25)
705 		  (else 'failed))
706 	   'x=-25)
707 (test-eval '(if true false true) false)
708 
709 (test-eval 
710  '(let ((x 4) (y 7))
711     (+ x y (* x y)))
712  (+ 4 7 (* 4 7)))
713 
714 
715 ;; and/or
716 (geval '(define x (+ 3 8)))
717 (test-eval '(and 0 true x) 11)
718 (test-eval '(and 0 true x false) false)
719 (test-eval '(and 0 true x (set! x -2) false) false)
720 (test-eval 'x -2)
721 (test-eval '(and 0 true x false (set! x -5)) false)
722 (test-eval 'x -2)
723 (test-eval '(or false (set! x 25)) 'ok)
724 (test-eval 'x 25)
725 (test-eval '(or (set! x 2) (set! x 4)) 'ok)
726 (test-eval 'x 2)
727 (test-eval '(or false (set! x 25) true false) 'ok)
728 (test-eval 'x 25)
729 (test-eval '(or ((lambda (x) x) 5)) 5)
730 (test-eval '(or (begin (set! x (+ x 1)) x)) 26)
731 
732 
733 ;; cond
734 
735 (test-eval 
736  '(cond ((assoc 'b '((a 1) (b 2))) => cadr)
737 	(else false))
738  2)
739 
740 (test-eval
741  '(cond ((= 3 4) 'not-true)
742 	((= (* 2 4) 3) 'also-false)
743 	((map (lambda (x)
744 		(* x (+ x 1)))
745 	      '(2 4 1 9))
746 	 =>
747 	 (lambda (x)
748 	   (accumulate + 0 x)))
749 	(else 'never-reach))
750  118)
751 ;; '(6 20 2 90)
752 
753 
754 ;; procedure definition and application
755 (geval
756  '(define (factorial n)
757     (if (= n 0)
758 	1
759 	(* n (factorial (- n 1))))))
760 (test-eval '(factorial 5) 120)
761 
762 ;; map
763 
764 (test-eval
765  '(map (lambda (x)
766 	 (* x (+ x 1)))
767        '(2 1 4 2 8 3))
768  '(6 2 20 6 72 12))
769 ;; accumulate
770 
771 (test-eval
772  '(accumulate + 0 '(1 2 3 4 5))
773  15)
774 
775 ;; make-let
776 (test-eval 
777  (make-let '(x y) '(3 5) '((+ x y)))
778  8)
779 (test-eval 
780  '(let ()
781     5)
782  5)
783 (test-eval
784  '(let ((x 3))
785     x)
786  3)
787 (test-eval
788  '(let ((x 3)
789 	(y 5))
790     (+ x y))
791  8)
792 (test-eval 
793  '(let ((x 3)
794 	(y 2))
795     (+ (let ((x (+ y 2))
796 	     (y x))
797 	 (* x y))
798        x y))
799  (+ (* 4 3) 3 2))
800 (test-eval
801  '(let ((x 6)
802 	(y (let ((x 2))
803 	     (+ x 3)))
804 	(z (let ((a (* 3 2)))
805 	     (+ a 3))))
806     (+ x y z))
807  (+ 6 5 9))
808     
809 
810 ;; let*
811 
812 (test-eval
813  '(let* ((x 3)
814 	 (y (+ x 2))
815 	 (z (+ x y 5)))
816     (* x z))
817  39)
818 
819 (test-eval
820  '(let* ()
821     5)
822  5)
823 (test-eval
824  '(let* ((x 3))
825     (let* ((y 5))
826       (+ x y)))
827  8)
828 
829 (test-eval 
830  '(let* ((x 3)
831 	 (y (+ x 1)))
832     (+ (let* ((x (+ y 2))
833 	      (y x))
834 	 (* x y))
835        x y))
836  (+ (* 6 6) 3 4))
837 (test-eval
838  '(let* ((x 6)
839 	 (y (let* ((x 2)
840 		   (a (let* ((x (* 3 x)))
841 			(+ x 2))))       
842 	      (+ x a)))                  
843 	 (z (+ x y)))                    
844     (+ x y z))
845  32)
846 
847 ;; named-let
848 
849 (test-eval
850  '(let eight ()
851     5
852     7
853     8)
854  8)
855 (test-eval
856  '(let loop ((count 0))
857     (if (= 100 count)
858 	count
859 	(loop (+ count 1))))
860  100)
861 (geval
862  '(define (prime? x)
863     (let prime-iter ((i 2))
864       (cond ((> (* i i) x) true)
865 	    ((= (remainder x i) 0) false)
866 	    (else (prime-iter (+ i 1)))))))
867 (test-eval
868  '(let primes ((x 2)
869 	       (n 20))
870     (cond ((= n 0) '())
871 	  ((prime? x) 
872 	   (cons x
873 		 (primes (+ x 1) (- n 1))))
874 	  (else (primes (+ x 1) n))))
875  '(2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71))
876 
877 (geval
878  '(define (fib n)
879     (let fib-iter ((a 1)
880 		   (b 0)
881 		   (count n))
882       (if (= count 0)
883 	  b
884 	  (fib-iter (+ a b) a (- count 1))))))
885 (test-eval '(fib 19) 4181)
886 
887 ;; do-loop	  
888 (test-eval
889  '(let ((y 0))
890     (do ((x 0 (+ x 1)))
891 	((= x 5) y)
892       (set! y (+ y 1))))
893  5)
894 (test-eval
895  '(do ()
896       (true))
897  true)
898 (test-eval
899  '(do ()
900       (true 5))
901  5)
902 (test-eval
903  '(let ((y 0))
904     (do ()
905 	((= y 5) y)
906       (set! y (+ y 1))))
907  5)
908 
909 (test-eval
910  '(do ((y '(1 2 3 4)))
911       ((null? y))
912     (set! y (cdr y)))
913  true)
914 (test-eval
915  '(let ((y 0))
916     (do ((x 0 (+ x 1)))
917 	((= x 5) y)
918       (set! y (+ y 1))))
919  5)
920 (test-eval
921  '(let ((x '(1 3 5 7 9)))
922     (do ((x x (cdr x))
923 	 (sum 0 (+ sum (car x))))
924 	((null? x) sum)))
925  25)
926 (test-eval 
927  '(let ((z '()))
928     (do ((x '(1 2 3 4) (cdr x))
929 	 (y '(1 2 3 4 5 6 7 8) (cddr y)))
930 	((null? x) y x z)
931       (set! z (cons (car x) z))))
932  '(4 3 2 1))
933 
934 
935 
936 ;; make-unbound!
937 ;; broken now due to scan-out-defines
938 
939 ;; (test-eval
940 ;;  '(let ((x 3))
941 ;;     (let ((x 5))
942 ;;       (make-unbound! x)
943 ;;       (* x x)))
944 ;;  9)
945 
946 ;; (test-eval
947 ;;  '(let ((x 3))
948 ;;     (let ((x 5))
949 ;;       (define y x)
950 ;;       (make-unbound! x)
951 ;;       (* y x)))
952 ;;  15)
953 
954 ;; (test-eval
955 ;;  '(let ((y -1) (x 3))
956 ;;     (let ((y 0.5) (x 5))
957 ;;       (define a x)
958 ;;       (define b y)
959 ;;       (make-unbound! x)
960 ;;       (make-unbound! y)
961 ;;       (* a b x y)))
962 ;;  (* 5 3 -1 0.5))
963 
964 ;; (test-eval
965 ;;  '(let ((x 3) (y 4))
966 ;;     (let ((x 5))
967 ;;       (make-unbound! x)
968 ;;       (+ x 4)))
969 ;;  7)
970 
971 ;; (test-eval 
972 ;;  '(let ((a 1) (b 2) (c 3) (d 4))
973 ;;     (make-unbound! b)
974 ;;     (+ a c d))
975 ;;  (+ 1 3 4))
976 
977 ;; (test-eval
978 ;;  '(let ((x 4) (y 5))
979 ;;     (let ((a 1) (b 2) (c 3))
980 ;;       (let ((x (+ a b)) (y (+ c a)))
981 ;; 	(make-unbound! x)
982 ;; 	(let ((a x) (b (+ x y)))
983 ;; 	  (define z b)
984 ;; 	  (make-unbound! b)
985 ;; 	  (* (+ a z)
986 ;; 	     (+ a b y))))))
987 ;;  (* (+ 4 8)
988 ;;     (+ 4 2 4)))
989  
990 ;; x 3 -- y 4
991 ;; x 4 -- y 4
992 ;; a 4 -- b 4
993 ;; a 4 -- b 2
994 
995 ;; scan-out-defines
996 
997 (geval
998  '(define (f x)
999     (define (even? n)
1000       (if (= n 0)
1001 	  true
1002 	  (odd? (- n 1))))
1003     (define (odd? n)
1004       (if (= n 0)
1005 	  false
1006 	  (even? (- n 1))))
1007     (even? x)))
1008 (test-eval '(f 5) false)
1009 (test-eval '(f 10) true)
1010 
1011 ;; (geval
1012 ;;  '(let ((x 5))
1013 ;;     (define y x)
1014 ;;     (define x 3)
1015 ;;     (+ x y)))
1016 ;; signal an error because x is undefined if variables are scanned out
1017 
1018 ;; letrec
1019 
1020 (geval
1021  '(define (f x)
1022     (letrec ((even?
1023 	      (lambda (n)
1024 		(if (= n 0)
1025 		    true
1026 		    (odd? (- n 1)))))
1027 	     (odd?
1028 	      (lambda (n)
1029 		(if (= n 0)
1030 		    false
1031 		    (even? (- n 1))))))
1032       (even? x))))
1033 (test-eval '(f 11) false)
1034 (test-eval '(f 16) true)
1035 
1036 (test-eval 
1037  '(letrec ((fact
1038 	    (lambda (n)
1039 	      (if (= n 1)
1040 		  1
1041 		  (* n (fact (- n 1)))))))
1042     (fact 10))
1043  3628800)
1044 
1045 
1046 ;; delayed-evaluation
1047 
1048 (geval
1049  '(define (try a b)
1050     (if (= a 0) 1 b)))
1051 (test-eval '(try 0 (/ 1 0)) 1)
1052 
1053 (geval 
1054  '(define (unless condition usual-value exceptional-value)
1055     (if condition exceptional-value usual-value)))
1056 (test-eval
1057  '(let ((a 4) (b 0))
1058     (unless (= b 0)
1059             (/ a b)
1060 	    (begin (display "exception: returning 0")
1061 		   0)))
1062  0)
1063 (test-eval
1064   '(let ((a 4) (b 2))
1065     (unless (= b 0)
1066             (/ a b)
1067 	    (begin (display "exception: returning 0")
1068 		   0)))
1069   2)
1070 
1071 (geval
1072  '(define (factorial n)
1073     (unless (= n 1)
1074             (* n (factorial (- n 1)))
1075 	    1)))
1076 (test-eval
1077  '(factorial 8)
1078  40320)
1079 
1080 (geval '(define count 0))
1081 (geval '(define (id x)
1082 	  (set! count (+ count 1))
1083 	  x))
1084 
1085 (geval '(define w (id (id 10))))
1086 (test-eval 'count 1)
1087 (test-eval 'w 10)
1088 (test-eval 'count 2)
1089 (test-eval
1090  '(let ((f (lambda (x) (+ x 1))))
1091     (f 1))
1092  2)
1093 (geval '(define count 0))
1094 (geval '(define (id x)
1095 	  (set! count (+ count 1))
1096 	  x))
1097 (geval 
1098  '(define (square x)
1099     (* x x)))
1100 (test-eval 
1101  '(square (id 10))
1102  100)
1103 (test-eval 'count 1)
1104 ;; would be 2 without memoization
1105 
1106 
1107 ;; streams
1108 
1109 (geval 
1110  '(define ones (cons 1 ones)))
1111 (geval
1112  '(define integers (cons 1 (add-lists ones integers))))
1113 (test-eval 
1114  '(list-ref integers 17)
1115  18)
1116 
1117 (geval
1118  '(define (integral integrand initial-value dt)
1119     (define int
1120       (cons initial-value
1121 	    (add-lists (scale-list integrand dt)
1122 		       int)))
1123     int))
1124 (geval
1125  '(define (solve f y0 dt)
1126     (define y (integral dy y0 dt))
1127     (define dy (map f y))
1128     y))
1129 (test-eval 
1130  '(list-ref (solve (lambda (x) x) 1 0.001) 1000)
1131  2.716924)